Change Access Query Criteria using Excel

Sub GetAccessParameterData()
   ' Sample demonstrating how to return a recordset from a parameterised query
   '#############################################################
   ' Requires reference to Microsoft ActiveX Data Objects library
   '#############################################################
   Dim cnn As ADODB.Connection
   Dim strQuery As String
   Dim cmd As ADODB.Command
   Dim rst As New ADODB.Recordset
   Dim prm As ADODB.Parameter, prms As ADODB.Parameters
   Dim strPathToDB As String
   Dim wks As Worksheet
   Dim i As Long
   
   Set wks = ActiveSheet
   
   ' change database path and query name as required
   strPathToDB = "C:\Test\db1.mdb"
   strQuery = "qselTestParam"
   
   Set cnn = New ADODB.Connection
   With cnn
      .Provider = "Microsoft.Jet.OLEDB.4.0"
      .ConnectionString = "Data Source=" & strPathToDB & ";"
      .Open
   End With
   Set cmd = New ADODB.Command
   With cmd
      Set .ActiveConnection = cnn
      .CommandText = strQuery
      .CommandType = adCmdTable
      .Parameters.Refresh
      
      ' Change parameter names as necessary
      .Parameters("[Start_ID]").Value = 1
      .Parameters("[Stop_ID]").Value = "Test man"
   End With
   
   rst.Open cmd
   With rst
      If Not (.EOF And .BOF) Then
               'Populate field names
         For i = 1 To .Fields.Count
            wks.Cells(1, i) = .Fields(i - 1).Name
         Next i
         ' Copy data
         wks.Range("A2").CopyFromRecordset rst
      End If
   End With
   rst.Close
   Set rst = Nothing
   Set cmd = Nothing
   cnn.Close
   Set cnn = Nothing
End Sub

Data Source=C:\mydatabase.mdb;Jet OLEDB:Database Password=MyDbPassword;