Getting a Cell Reference from a Combo Box in a User Form

With ComboBox1
     MsgBox Range(.RowSource).Cells(.ListIndex + 1,1).Address & " is where the selected item is located"
End With

Option Explicit

Private LISelected As Long
Private LIRange As Range
Private IgnoreChange As Boolean
Private ListItems As Variant
Private WasEdited As Boolean

Private Sub ComboBox1_Change()
    If IgnoreChange Then Exit Sub
    
    If ComboBox1.ListIndex <> -1 Then
        LISelected = ComboBox1.ListIndex
    Else
        If LISelected <> -1 Then
            LIRange(LISelected + 1) = ComboBox1.Text
            IgnoreChange = True
            UpdateComboList
            IgnoreChange = False
            WasEdited = True
        End If
    End If
End Sub

Private Sub ComboBox1_Exit(ByVal Cancel As MSForms.ReturnBoolean)
    If IgnoreChange Then
        IgnoreChange = False
        Exit Sub
    End If
    
    If WasEdited Then
        If MsgBox("Commit changes?", vbYesNo + vbCritical) <> vbYes Then
            LIRange = ListItems
            IgnoreChange = True
            UpdateComboList
            ComboBox1.Text = "Select an Item"
            IgnoreChange = False
        End If
        WasEdited = False
    End If
End Sub

Private Sub UserForm_Initialize()
    LISelected = -1
    Set LIRange = [ComboBox1RowSource]
    ListItems = LIRange
    ComboBox1.MatchEntry = fmMatchEntryNone
    UpdateComboList
    ComboBox1.Text = "Select an Item"
End Sub

Private Sub UpdateComboList()
    ComboBox1.Clear
    ComboBox1.List = Application.Transpose(LIRange)
End Sub

Private Sub CommandButton1_Click()
    Unload Me
End Sub

    ComboBox1.Column = LIRange.Value