Combine Three Text Files in Access VBA

Public Function MyCombineFilesFunc(myFileDir As String, myHeader As String, myDetails As String, myTrailer As String, myFinalFile As String)
'   Calls combine files procedure
 
    Dim myFileDirExp As String
 
'   Check for missing backslash on end of file dir
    If Right(myFileDir, 1) <> "\" Then
        myFileDirExp = myFileDir & "\"
    Else
        myFileDirExp = myFileDir
    End If
 
'   Call procedure to combine files
    Call MyCombineFiles(myFileDirExp, myHeader, myDetails, myTrailer, myFinalFile)
 
End Function

Public Sub MyCombineFiles(myFileDir, myHeader, myDetails, myTrailer, myFinalFile)
'   Combines designated files in a given file path (in the same path) and deletes the originals
'   Code from Jim Rech, [URL]http://groups.google.com/group/microsoft.public.excel.programming/browse_thread/thread/17039bd4f6a8563b[/URL]
 
'   myFileDir = location where files to combine reside
'   myHeader = name of Header file to combine
'   myDetails = name of Detail file to combine
'   myTrailer = name of Trailer file to combine
'   myFinalFile = name of final combine files
 
    Dim SrcFiles
    Dim CurrSrc As String
    Dim DestFile As String
    Dim Counter As Integer
    Dim TextLine As String
 
'   Combine files
    SrcFiles = Array(myFileDir & myHeader, myFileDir & myDetails, myFileDir & myTrailer)
    Open myFileDir & myFinalFile For Output As #1
    For Counter = 0 To UBound(SrcFiles)
        Open SrcFiles(Counter) For Input As #2
        Do While Not EOF(2)
            Line Input #2, TextLine
            Print #1, TextLine
        Loop
        Close #2
    Next
    Close #1
 
'   Delete temp files
    Kill myFileDir & myHeader
    Kill myFileDir & myDetails
    Kill myFileDir & myTrailer
 
End Sub

Public Sub MyCombineFiles(myFileDir As String, myFileExt As String, myFinalFileName As String)
'   This process will combine all text files in a directory into one single file (should only be used with text files)
'   myFileDir = location where files to combine reside (including final backslash)
'   myFileExt = file extension of files you want to copy (including period)
'   myFinalFileName = file name and extension of final combined file

    Dim fname
    Dim TextLine As String
    Dim myCombinedFile As String

'   Create output file
    myCombinedFile = myFileDir & myFinalFileName
    Open myCombinedFile For Output As #1
    
'   Loop through all files with designated extension in the directory
    fname = Dir(myFileDir & "*" & myFileExt)
    While (fname <> "") And (fname <> myFinalFileName)
'   Open file and write data to output file
        Open myFileDir & fname For Input As #2
        Do While Not EOF(2)
            Line Input #2, TextLine
            Print #1, TextLine
        Loop
        Close #2
'   Delete initial file after it is merged (comment this line out if you do not want to delete initial files)
        Kill myFileDir & fname
'   Go to the next file
        fname = Dir()
    Wend
    Close #1

End Sub